Let's say I have three variables in SPSS, each being answered on a Likert Scale of 1-5 (little to much):
How much do you enjoy chocolate ice cream?
How much do you enjoy strawberry ice cream?
How much do you enjoy vanilla ice cream?
Say I want to, for each case, select the highest value of the three aforementioned variables and recode that into a new variable (to indicate the maximum level of ice cream enjoyment). Is there a way I can do this using a syntax in SPSS?
Hi,,
this is the formula [just between brackets, change a,b,c, to your variables name]
COMPUTE max=MAX(a,b,c).
EXECUTE.
Maybe:
COMPUTE maximum_var=MAX(var_1,var_2,var_3).
EXECUTE.
Cheerz,
Rainer
Hi,,
this is the formula [just between brackets, change a,b,c, to your variables name]
COMPUTE max=MAX(a,b,c).
EXECUTE.
I really do not see why you need syntax for such a problem. You can use frequecies from Analyze, choose max for the list of your variablesand then the max of list of maxima you get
Dear Muhammad,
isn't it easier the way Muayyad and I proposed? 2 lines of code, no clicking, less prone to errors and you have a complete new variable with which you can do other analyses? (unmentioned the fact that I recommend to use syntax for nearly everything, simply to archive what you did, and it is easier to adapt for your needs and purposes).
John, what do you want to do in the case of missing data? The following syntax demonstrates some of your options. HTH.
* Turn off warning messages due to missing values
* in the following DATA LIST command.
PRESERVE.
SET MXWARNS=0.
DATA LIST list / v1 v2 v3 (3F1).
BEGIN DATA
1 2 3
1 3 2
2 1 3
2 3 1
3 1 2
3 2 1
1 2 .
1 . 3
1 2 .
1 . .
. 2 .
. . 3
. . .
END DATA.
* Restore MXWARNS to the default value.
RESTORE.
* Demonstrate how MAX vs MAX.n functions
* handle missing values differently.
COMPUTE MAX1a = MAX(v1 to v3).
COMPUTE MAX1b = MAX.1(v1 to v3).
COMPUTE MAX2 = MAX.2(v1 to v3).
COMPUTE MAX3 = MAX.3(v1 to v3).
FORMATS MAX1a to MAX3(F1).
LIST.
OUTPUT from LIST (view with fixed font to make things line up):
v1 v2 v3 MAX1a MAX1b MAX2 MAX3
1 2 3 3 3 3 3
1 3 2 3 3 3 3
2 1 3 3 3 3 3
2 3 1 3 3 3 3
3 1 2 3 3 3 3
3 2 1 3 3 3 3
1 2 . 2 2 2 .
1 . 3 3 3 3 .
1 2 . 2 2 2 .
1 . . 1 1 . .
. 2 . 2 2 . .
. . 3 3 3 . .
. . . . . . .
Number of cases read: 13 Number of cases listed: 13
I have a related, but slightly different question:
Instead of having the value from the highest variable in the new variable, I want a categorical coding in the new variable indicating from which of the three original variables the value came from. Does anyone know how to do that?
Jan Luca, you're more likely to get responses to questions like this in the SPSSX-L discussion forum (http://spssx-discussion.1045642.n5.nabble.com/).
See the IBM Technote linked below. Alternatively, you could tinker with the syntax shown in David Marso's post to SPSSX-L (second link below). E.g., here is a modified version of his code that finds the 3 highest scores in a set of 10 and indicates which variables they are held by.
* Generate some data to demonstrate.
DATA LIST FREE / x1 to x10.
BEGIN DATA.
13 54 23 54 25 12 52 3 51 23
15 41 23 15 42 31 23 12 15 12
51 43 51 36 12 53 6 12 53 12
63 51 23 51 73 51 35 12 35 35
END DATA.
** TO GET MAXIMUMS AND THEIR LOCATION ** .
VECTOR WHAT (3) / WHERE(3)/X=X1 TO X10.
RECODE Where1 TO Where3 (ELSE=0).
LOOP #=1 to 3.
+ COMPUTE WHAT(#)=MAX(X1 TO X10).
+ COMPUTE #FOUND=0.
+ LOOP #Ind =1 TO 10.
+ DO IF X(#Ind)=WHAT(#) AND NOT (#FOUND).
+ COMPUTE WHERE(#)=#Ind.
+ COMPUTE X(#Ind)=-X(#Ind).
+ COMPUTE #FOUND=1.
+ END IF.
+ END LOOP IF #Found.
END LOOP.
DO REPEAT X=X1 TO X10.
IF X < 0 X=-X.
END REPEAT.
FORMATS ALL (F2.0).
LIST.
http://www-01.ibm.com/support/docview.wss?uid=swg21476419
http://spssx-discussion.1045642.n5.nabble.com/Tweaking-Identify-3-Highest-Values-within-Each-Case-td5731751.html
How to do generate min/max/mean for a single variable -i.e. uni-variate statistic and then use it in a formula in Transform->compute window
George, use the AGGREGATE command with MODE=ADDARIABLES to add 3 new variables (min, max and mean) to your working dataset. Then carry out your computations. HTH.
- https://www.ibm.com/support/knowledgecenter/en/SSLVMB_25.0.0/statistics_reference_project_ddita/spss/base/syn_aggregate.html
- https://www.spss-tutorials.com/spss-aggregate-command/
AT THE MENU SPSS CLICK TRANFORM
THEN SELECT COMPUTE VARIABLE
FROM THE FEW VARIABLE WE CAN FIND THE MAX VALUE REPRESENT FOR THE NEW VARIABLE
EXAMPLE CODE FOR MY CASE:
MAX (BPE_SEXT1, BPE_SEXT2, BPE_SEXT3)
MAX( 1, 2, 3)
I WILL GET 3 FOR THE FIRST N.
TQ SO MUCH
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS