I am working with some follow-up data in the wide format and trying to recode the value 'No Change = 6' to the value imputed at the previous time point (for the same patient ID) using SPSS.
I've tried to show an example below
PID Partnership.1 Partnership.2 Partnership.3
1 1 6 4
2 3 3 5
3 4 6 4
4 2 2 6
Hello Sophia,
As long as there are just the three scores, the following syntax would appear to fit your needs:
if (Partnership2 = 6) Partnership2 = Partnership1 .
execute .
if (Partnership3 = 6) Partnership3 = Partnership2 .
execute .
Good luck with your work.
Here's a more general solution that is scalable for any number of variables.
*** Start of syntax ***.
NEW FILE.
DATASET CLOSE ALL.
DATA LIST LIST / PID p1 to p3 (4F1).
BEGIN DATA
1 1 6 4
2 3 3 5
3 4 6 4
4 2 2 6
5 1 6 6
END DATA.
VECTOR p = p1 to p3.
LOOP # = 2 to 3.
IF p(#) EQ 6 p(#) = p(#-1).
END LOOP.
* Use DESCRIPTIVES rather than EXECUTE to cause
* the pending transformations to be executed.
* You might as well get some output for your trouble.
* The output should show Max < 6 for all variables.
DESCRIPTIVES p1 to p3.
*** End of syntax ***.
Listing the records after executing that code shows this:
PID p1 p2 p3
1 1 1 4
2 3 3 5
3 4 4 4
4 2 2 2
5 1 1 1
Number of cases read: 5 Number of cases listed: 5
try this:
do if Partnership.2 = 6.
compute Partnership.2 = Partnership.1.
end if.
do if Partnership.3 = 6.
compute Partnership.3 = Partnership.2.
end if.
exe.
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS