Hello.. I have 2 variables (flu2020 and flu 2019) which reflect the number of pharmacies offering the flu vaccine and 2020 and 2019. I wanted to compare the % to check if the difference between the two proportions is significant. I ran chi-square test and Fisher's exact test on SAS and that was the only table showing in the output (photo attached) and in the log I found this note: "No statistics are computed for adult3 * adult11 because adult3 has fewer than 2 nonmissing levels."
I tried doing the same using SPSS but then I received this error message:
"at least one variable is constant".
I used the Fisher's exact test calculators available on the internet and I got a result however I want to make sure that I am doing it right.
Could someone please help with this?
What are the actual counts you have? Are there zero "no" observations for flu2020 ?
Another question: are you comparing the same pharmacies for each year ? That is, if you had a table that had 2019Yes and 2019No as columns and 2020Yes and 2020No as rows, the Yes-Yes count would enumerate those pharmacies that were Yes in 2019 and Yes in 2020. Is this the way you are collecting the data?
thanks for answering.
41.6%(2019) vs 44.2% (2020).
Yes, the table should look like the one in the photo (attached) but SAS omits the (no level since it had zero values)
Thanks for the response.
• I think that the way you have your table set up doesn't answer the question you are asking. (?) But I have no idea where you are getting e.g. 41.6% for 2019. So, I'm really not sure what question you are trying to answer.
• The way you have your table set up would suggest the use of McNemar's test, not a chi-square test of association or Fisher's exact test. In this case you have 1 observation that changed from No to Yes, and 0 that changed from Yes to No. Is this what you are interested in? You probably don't need a test to tell you that this isn't much of a change.
• In the code, the problem is probably that you need to include the zeros option in the weight command, telling SAS to allow a zero cell count. I'm not entirely sure. I haven't worked that much with SAS and contingency tables.
The example here compares the frequencies from 2019 to those from 2020.
data Tabla;
input Year $ Vaccine $ count;
datalines;
2019 Yes 76
2019 No 1
2020 Yes 77
2020 No 0
;
proc freq data=Tabla order=data;
tables Year*Vaccine / chisq expected norow nocol nopercent;
weight count / zeros;
run;
No problem.
For the reader, below I have SAS code for both McNemar's test and for Chi-square test of association (and Fisher exact test). I created some hypothetical data.
Note that in my hypothetical data, the table set-up for McNemar's has a total of 118, while the table set-up for chi-square has a total of 236 (118 x 2).
* McNemar test, and exact McNemar test (binomial test)
* Note that the total counts in the table is 118
data Table1;
input Year2019 $ Year2020 $ count;
datalines;
Yes Yes 76
Yes No 7
No Yes 12
No No 23
;
proc freq data=Table1 order=data;
tables Year2019*Year2020 /agree;
exact mcnem;
weight count / zeros;
run;
*******************************************
* Chi-square test and Fisher exact test
* Note that the total counts in the table is 236 (118 x 2)
data Table2;
input Year $ Vaccine $ count;
datalines;
2019 Yes 83
2019 No 35
2020 Yes 88
2020 No 30
;
proc freq data=Table2 order=data;
tables Year*Vaccine / chisq expected norow nocol nopercent;
weight count / zeros;
run;
If this is data on the same pharmacies for two years, then you have repeated measurements, not two samples. In this case, McNemar is the test you need.
As far as I can see from your table, all but one of the pharmacies offered the vaccine both years, and one switched from not offering to offering. In this case, you don't really need a statistical test, and, indeed, none is possible because McNemar relies only on the cells of the table that change, with the hypothesis that the proportion of switchers who switch from No to Yes is the same as the proportion that switches the other way around. Since you only have one pharmacy that switched, bets are off.
- Badges
- Science topic
- Similar topics
- Biological Science
- Biochemistry
- Enzymology
- Enzymes