I am attempting to compare data from a subset of participants (demander cases) in a large dataset with a gender and education matched control group (supplier cases) in a dataset, at a ratio of 1:5. So far I have managed to run the case-control matching procedure in SPSS, and I now have 5 new variables, where the participant ID numbers of the 5 matched supplier cases are entered as values for each corresponding demander participant. I'm not sure what to do now to turn this into a variable (or new dataset?) that can be analysed. I would like to now compare means of the the demander/supplier groups across a number of variables. It seems to be straightforward with the demander/supplier ratio is 1:1, but not as straightforward when it is not. Hoping someone has done this before on SPSS and can advise, as my online searches have come up with nothing. Thank you!
Hi Sophie,
I had this challenge a few years ago. Here's how I approached it. Note there is quite a bit of data management.
1. Generate your matches. I used the following to guide me through this:
https://cair.org/wp-content/uploads/sites/474/2015/07/TaingA-Case-controlMatching.pdf
See the last two pages for the walk through.
Note, you can use Fuzzy to get matches based on both exact or fuzzy matches.
2. Once you've worked through the Fuzzy procedure you'll end up with a dataset that ends with a series of match_id variables, for example: match_id, match_id2, match_id3. Each match_id represents the id number of the control that matches your case.
3. Make a copy of the dataset and then filter on only the matched cases. Here is the syntax I used for this.
DATASET COPY MATCHES WINDOW=FRONT.
IF RTRIM(match_id) NE "" tempfilter = 1.
CROSS tempfilter by vGROUP.
SELECT IF tempfilter.
You'll now have a dataset that only contains your matched cases and controls.
Next, I removed all variables except my Case Identifier and the Control Match_Ids using SPSS' DELETE VARIABLES command.
Finally I renamed this dataset as follows:
DATASET NAME WIDE.
4. Using the WIDE dataset you created in 3, create a dataset that holds your Case data and one dataset for each matching control. So for my study I was matching at a 1:3 ratio, so I had 4 datasets. Here is the syntax I used to create these datasets:
DATASET COPY dCASE WINDOW=FRONT.
DATASET COPY dCONTROL1.
DATASET COPY dCONTROL2.
DATASET COPY dCONTROL3.
5. Now we need to populate each of the CASE/CONTROL datasets with data from our master dataset. Here is a snippet of the code I used to populate CASE.
DATASET ACTIVATE MASTERDATA WINDOW=FRONT.
DATASET COPY SOURCE WINDOW=FRONT.
DELETE VARIABLES any variables you do not need.
SORT CASES BY Identifier (A).
DATASET ACTIVATE dCASE WINDOW=FRONT.
SORT CASES BY Identifier (A).
* Given this is the case dataset, remove the Control IDs.
DELETE VARIABLES Match_ID TO MATCH_ID3.
* Add our data to our CASE file.
DATASET ACTIVATE dCASE.
MATCH FILES /FILE=*
/TABLE='SOURCE'
/BY Identifier.
EXECUTE.
* We'll also add a nMatch variable to indicate match number. So for a Case nMatch=0 for Control 1, nMatch =1, for Control 2 nMatch =2, etcetera.
COMPUTE nMATCH=0.
EXECUTE.
* Ok, now we repeat the above process for our Control datasets, starting with CASE1.
DATASET ACTIVATE dCONTROL1 WINDOW=FRONT.
* Remove all control IDs, except control 1.
DELETE VARIABLES match_id2 match_id3.
* Replace our Identifier (ID) variable with the Control ID.
RENAME VARIABLES Identifier=i1.
RENAME VARIABLES match_id=Identifier.
* Add our data to the CASE1 file.
SORT CASES BY identifier.
MATCH FILES /FILE=*
/TABLE='SOURCE'
/BY Identifier.
EXECUTE.
* Set nMatch to whatever Control subject this is. In this case it is the first of three, so set it to 1.
COMPUTE nMATCH=1.
EXECUTE.
* REPEAT this process for each CONTROL case.
6. Ok, now you will have one dataset per CASE and CONTROL. You know simply need to merge these together into one LONG dataset.
Here is some sample code:
* Activate the case dataset.
DATASET ACTIVATE dCASE WINDOW=FRONT.
* If i1s sizes differ across your CASE and CONTROL datasets, you may need to adjust the length of i1 (e.g., A30 instead of A10).
STRING i1(A10).
COMPUTE i1=identifier.
EXECUTE.
* Merge in each of the CONTROL Files.
ADD FILES /FILE=*
/FILE='dCONTROL1'.
EXECUTE.
ADD FILES /FILE=*
/FILE='dCONTROL2'.
EXECUTE.
ADD FILES /FILE=*
/FILE='dCONTROL3'.
EXECUTE.
DATASET CLOSE dCONTROL1.
DATASET CLOSE dCONTROL2.
DATASET CLOSE dCONTROL3.
* Sort the dataset by the CASE and then its CONTROL1 - 3.
SORT CASES BY i1 nMatch.
7. Currently the CASE file (which has all our data) is on LONG format. That is one record per case/control. We now need to convert this file to WIDE format so that we can compute the means for each set of CONTROLS.
Here is the code to convert from LONG to WIDE.
* CONVERT TO WIDE.
DATASET COPY WIDE WINDOW=FRONT.
SORT CASES BY i1 nMATCH.
CASESTOVARS
/ID=i1
/INDEX=nMATCH
/GROUPBY=VARIABLE.
8. Now you'll want to compute the mean score for each set of CONTROLS. I used a macro for this. You may not be comfortable with macro coding, so here is the non-macro version (and then I have the macro below). Let's say you wanted to compare Age.
COMPUTE Age_Mean = MEAN.1 (Age.1, Age.2, Age.3).
VARIABLE LABELS Age_Mean "Age_Controls".
VARIABLE LABELS Age.0 "Age_Case".
Now you can run a t-test comparing the mean age of your cases to controls as follows:
T-TEST PAIRS=Age.0 WITH Age_Mean (PAIRED)
/CRITERIA=CI(.9500)
/MISSING=ANALYSIS.
Given I compared a few different variables, I macro'd this but you don't need to. You could simply repeat the above code as many times as you need to for your analyses.
Here is my macro.
See the attachment for this code. When I include the code in the post it causes an upload error.
9. Remember the link I referred you to in the beginning?
https://cair.org/wp-content/uploads/sites/474/2015/07/TaingA-Case-controlMatching.pdf
Now you'll want to run Step 4. I used the above macro for this. Here is my code:
* FIRST CHECK MATCH.
* EXAMINE MATCH.
* NOTE that Gender and Site were exact matches (zero tolerance variables), so no need to check those.
!Alt_Test VarLIST (vAGE v_s_years p_years).
* Looks good!.
Finally you can use the above macro to perform your analysis, alternatively if you have a different type of analysis, you can now run it.
So, I was comparing mean scores for several domains, here is my syntax:
* COMPARE Domain SCORES.
!Alt_Test VarLIST (Domain1 Domain2 Domain3 Domain4).
10. Remember you still have your CASE dataset which is a LONG format of your data.
Let me know if you found this step by step helpful. :)
Sach
If I understand the problem correctly, I think you could use the MIXED command to estimate a random intercept model similar to the one shown on this UCLA page:
- https://stats.oarc.ucla.edu/spss/seminars/spss-mixed-command/
You would need a long file format with one row per person and the following variables (your variables may have different names):
- CID = cluster ID; ranges from 1 to number of clusters (i.e., match groups)
- Demander = indicator for demander status (1=demander, 0=supplier)
Variable CID would have the same value for all 6 members of a cluster group. One member of each cluster group would have Demander=1, and the other 5 would have Demander=0. (Or the other way around if I misunderstood the nature of the 5:1 matching.)
The code would look something like this:
MIXED dv WITH Demander {+ other variables}
/FIXED demander {+ other variables}
/RANDOM intercept | subject(CID)
/PRINT = solution.
The test for Demander (in the table of coefficients) is a test on the mean difference between demanders and suppliers that takes into account the 5:1 matching and with adjustment for the other variables that are included. I think that is what you are asking for, is it not?
HTH.
PS- Because variable Demander is a 1/0 variable, you can specify either WITH Demander (which treats it as a continuous/metric variable) or BY Demander (which treats it as categorical). The sign of the coefficient may differ using BY rather than WITH, but the absolute values will match as will the p-values. (See the example on that same web page comparing WITH female to BY female.)
After re-reading the original question, I now see that my first reply did not address your current data management problem. Rather, it suggested a way to carry out the analyses you want after the data have been restructured appropriately.
You wrote:
So far I have managed to run the case-control matching procedure in SPSS, and I now have 5 new variables, where the participant ID numbers of the 5 matched supplier cases are entered as values for each corresponding demander participant. I'm not sure what to do now to turn this into a variable (or new dataset?) that can be analysed.
It would help (me) a lot if you attached a small CSV file (with variable names in row 1) showing the structure of the current dataset. Is that possible? Thanks.
Hi Sophie and Bruce,
Sophie, it was bothering me that I didn't actually provide an example you could try for yourself. So, using one of the SPSS example datasets, I've generated code.
Bruce and I reviewed the code and also tweaked it accordingly. Here you go. Let us know if its helpful.
Sach
* Encoding: windows-1252.
OUTPUT CLOSE ALL.
OUTPUT NAME=WORKING.
DATASET CLOSE ALL.
* Unicode=ON is required for FUZZY.
NEW FILE.
DATASET NAME ForUnicode.
SET UNICODE ON.
* ***************************************************** .
* Set up the data file: For illustrative purposes only.
* ***************************************************** .
* Get Sample from your SPSS directory.
GET
FILE='C:\Program Files\IBM\SPSS\Statistics\27\Samples\English\survey_sample.sav'.
DATASET NAME Survey WINDOW=FRONT.
* Close For Unicode.
DATASET CLOSE ForUnicode.
* For illustrative purposes, let's create a variable to represent case and controls.
COMPUTE tCASE_NUM = $CASENUM.
FREQ tCASE_NUM /STAT.
COMPUTE CASECONTROL = 0.
IF tCase_NUM < 451 CASECONTROL = 1.
VALUE LABELS CASECONTROL 0 "Control" 1 "Case".
DESC CASECONTROL.
* Let's also create some fictious outcome data.
DEFINE !GenDomainScores (VarLIST !ENCLOSE("(",")"))
!do !Var !in (!VarList)
COMPUTE !Var = RND(RV.NORMAL(50,10)).
!doend.
!do !Var !in (!VarList)
IF CASECONTROL=1 AND !Var = Domain1 !Var = RND(RV.NORMAL(49,5)).
IF CASECONTROL=1 AND !Var = Domain2 !Var = RND(RV.NORMAL(49,8)).
IF CASECONTROL=1 AND !Var = Domain3 !Var = RND(RV.NORMAL(45,5)).
IF CASECONTROL=1 AND !Var = Domain4 !Var = RND(RV.NORMAL(40,5)).
DESCRIPTIVES !Var /STAT.
!doend.
!ENDDEFINE .
!GenDomainScores VarList (Domain1 Domain2 Domain3 Domain4).
FREQUENCIES Domain1 TO Domain4 /STAT.
MEANS DOMAIN1 TO DOMAIN4 BY CASECONTROL /STATISTICS ALL.
* ***************************************************** .
* Demonstrate how to use FUZZY to perform a match.
* ***************************************************** .
* Now lets use FUZZY to perform our match.
* Lets assume we are matching on sex, age, and race.
* Note that with 'FUZZ=' we are asking FUZZY to match sex, race, and age perfectly (FUZZ = 0 0 0). However, if you wanted a propensity match, then adjust the FUZZ subcommand, e.g., age by 1 year, then FUZZ = 0 1 0.
* Once our dataset is created we will check to make sure that this match is not significantly different. If it is, we'll want to lower our tolerance.
* The pro of lowering our tolerance is that we allow for a closer match. The con is that the match may differ by too much.
* DELETE VARIABLES DP_Size TO match_id5. Undelete this if you need to re-run FUZZY.
FUZZY BY=sex age race SUPPLIERID=id NEWDEMANDERIDVARS=Match_ID1 Match_ID2 Match_ID3 Match_ID4 Match_ID5
GROUP=CASECONTROL FUZZ=0 0 0 EXACTPRIORITY=FALSE
MATCHGROUPVAR=MSG DRAWPOOLSIZE=DP_Size
/OPTIONS SAMPLEWITHREPLACEMENT=FALSE MINIMIZEMEMORY=TRUE SHUFFLE=TRUE SEED=1234.
* Note that we have 1426 exact matches.
* ***************************************************** .
* Ok, this part actually answers Sophie's question.
* ***************************************************** .
* How many cases had 5 total matches?.
COMPUTE TotalMatches = NVALID(match_id1 TO MATCH_id5).
COMPUTE AllFive = 0.
IF NVALID(match_id1 TO match_id5) = 5 AllFive = 1.
FREQ AllFive /STAT.
CROSS AllFive by CaseControl.
CROSS TotalMatches BY CaseCOntrol.
* Note, we have 233 with all 5 matches...
* Create a dataset with cases and any matches.
DATASET COPY MATCHES WINDOW = FRONT.
DATASET ACTIVATE MATCHES.
SELECT IF ANY(TotalMatches,1,2,3,4,5).
FREQUENCIES TotalMatches /STAT.
* KEEP JUST ID VARIABLES.
DELETE VARIABLES wrkstat TO MSG.
* CREATE A LONG FILE WITH EACH ROW REPRESENTING EITHER A CASE OR ITS CONTROLS.
VARSTOCASES
/ID=i1
/MAKE ID FROM id match_id1 match_id2 match_id3 match_id4 match_id5
/INDEX=nMATCH(6)
/KEEP=TotalMatches AllFive
/NULL=DROP.
* For Cases, set nMatch = 0. Controls will have an nMatch between 1 and 5.
COMPUTE nMATCH=nMATCH-1.
EXECUTE.
* Ok, populate dataset.
DATASET ACTIVATE Survey WINDOW=FRONT.
SORT CASES BY id (A).
DATASET ACTIVATE MATCHES WINDOWS=FRONT.
SORT CASES BY ID.
MATCH FILES /FILE=*
/TABLE='SURVEY'
/BY id.
EXECUTE.
SORT CASES BY i1 ID.
* Populate CASE ID variable for sorting purposes.
DATASET ACTIVATE MATCHES WINDOW=FRONT.
ADD FILES FILE * /keep i1 id nMATCH TotalMatches AllFive Domain1 TO Domain4 ALL.
EXECUTE.
SORT CASES BY i1 nMatch id.
FREQ nMatch /STAT.
* Ok, we now have a LONG format file that contains all our data.
* ***************************************************** .
* Some sample analyses are below...
* ***************************************************** .
OUTPUT NEW NAME=MIXED_ALLFIVE.
* To compare our Cases to Controls is via a mixed model.
* One advantage of this is that we can control for other factors while controlling for the clustered nature of the data.
* See Bruce Weaver's post for more.
* If the post has been removed, see UCLA's "An example of the mixed command accounting for clustering" via https://stats.oarc.ucla.edu/spss/seminars/spss-mixed-command/ for more.
DATASET ACTIVATE MATCHES WINDOW=FRONT.
SORT CASES BY i1 nMATCH.
DEFINE !Mixed_Test (VarLIST !ENCLOSE("(",")"))
!do !Var !in (!VarList)
MIXED !Var BY CASECONTROL
/FIXED CASECONTROL
/RANDOM intercept | subject(i1)
/PRINT = solution
/EMMEANS TABLES(CASECONTROL) COMPARE(CASECONTROL).
!doend
!ENDDEFINE .
FILTER BY AllFive.
!Mixed_Test VarLIST (Domain1 Domain2 Domain3 Domain4).
* Note, some of our analyses are failing to converge...
OUTPUT NEW NAME=ADJUSTED_ANALYSIS.
* One last comment, you could forgo matching and simply adjust for your match variables.
* The advantage of this approach is that you utilize all available cases versus those with matches, essentially increasing your power to detect a difference.
* In the EMMEANS command I've set the matching variables to the mean values.
DEFINE !Uni_Test_unadjusted (VarLIST !ENCLOSE("(",")"))
!do !Var !in (!VarList)
UNIANOVA !Var BY CASECONTROL race WITH sex age
/METHOD=SSTYPE(3)
/CONTRAST(CASECONTROL)=SIMPLE(1)
/INTERCEPT=INCLUDE
/PRINT=ETASQ DESCRIPTIVE PARAMETER
/CRITERIA=ALPHA(.05)
/EMMEANS=TABLES(CASECONTROL) WITH(age=MEAN sex=MEAN) COMPARE ADJ(LSD)
/DESIGN=CASECONTROL sex age race.
!doend
!ENDDEFINE .
DATASET ACTIVATE Survey WINDOW=FRONT.
!Uni_Test_unadjusted VarLIST (Domain1 Domain2 Domain3 Domain4).
* Note, these results will vary each time you run them given DOMAIN1 - 4 scores are randomly generated.
* Domain 2 seems counter-intuitive but remember the data are randomly generated so I imagine in practice UNIANOVA will trend towards have a lower p-value.
* DOMAIN 1: Mixed, t=2.268, p = .023; UNIANOVA: t=2.323, p = .020.
* DOMAIN 2: Mixed, t=1.966, p = .049; UNIANOVA: t=1.873, p = .061.
* DOMAIN 3: Mixed, t=8.510, p < .001; UNIANOVA: t=10.222, p < .001.
* DOMAIN 4: Mixed, t=13.905, p < .001; UNIANOVA: t=19.518, p < .001.
* TURN UNICODE BACK OFF (to save yourself grief later).
DATASET CLOSE ALL.
NEW FILE.
DATASET NAME ForUnicode.
SET UNICODE OFF.
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS