I'm using Hayes' PROCESS macro in SPSS to carry out a moderation analysis. I have two dummy variables (IV1 and IV2), one moderator variable (W) and one DV (Y).
As the dialog box does not allow for two IVs to be entered together, I have tried to use a work-around whereby IV1 is entered in the IV box and IV2 is entered in the covariate box. The issue with this is that it only provides one interaction term output (IV1 x W). I also need IV2 x W. Therefore, I have re-run the analysis switching the positions of IV1 and IV2 and this gives me the output for IV2 x W however, the output figures do not match the first output (for the main and overall effects).
Is this difference expected? Am I running the analysis correctly or is there another model I should be using?
Hello Lydia Day. Why do you need to use the PROCESS macro? You can easily estimate that model via the UNIANOVA command (or GLM). In the dialog for UNIANOVA, enter the two dichotomous variables as "fixed factors" and the continuous variable as a "covariate". Then use EMMEANS sub-commands to get 2x2 tables of estimated marginal means for the 2x2 combination of the dichotomous variables at selected values of the effect modifier. You can also add a COMPARE option to get simple effects of one variable at both levels of the other. It's all fairly straightforward for a design like yours. HTH.
Bruce Weaver Thank you very much for your response! We were taught and advised to use PROCESS in class. I understand the first part of your response (entering the variables in the UNIANOVA command) however, the second part has confused me slightly. In the Options dialog box, how would I go about producing 2x2 tables of estimated marginal means combination of the dichotomous variables at selected values of the effect modifier?
TIA
Here is a very quick & dirty example. I've attached the 1991 GSS data file, as I'm not sure if it still comes with recent versions of SPSS. I hope this helps get you started.
NEW FILE.
DATASET CLOSE ALL.
* Modify path as needed.
GET FILE='C:\SPSSdata\1991 U.S. General Social Survey.sav'.
FREQUENCIES sex race.
* To make this a 2x2 (like Lydia has), compute a new variable
* called White, and combine the Black & Other categories for race.
COMPUTE white = race EQ 1.
FORMATS white (F1).
CROSSTABS race by white.
* Run a model with DV = prestg80, focal explanatory variables = sex & white,
* moderator (or interacting) variable = age.
* Run it via UNIANOVA rather than REGRESSION so that
* sex and white can be treated as factor variables.
* Save fitted values & residuals in case you want to plot them.
UNIANOVA prestg80 BY sex white WITH age
/SAVE=PRED(Yprime) RESID (Residual)
/EMMEANS=TABLES(sex) WITH(age=MEAN) compare /* the default */
/EMMEANS=TABLES(sex) WITH(age=20) compare
/EMMEANS=TABLES(sex) WITH(age=40) compare
/EMMEANS=TABLES(sex) WITH(age=60) compare
/EMMEANS=TABLES(sex) WITH(age=80) compare
/EMMEANS=TABLES(white) WITH(age=MEAN) compare /* the default */
/EMMEANS=TABLES(white) WITH(age=20) compare
/EMMEANS=TABLES(white) WITH(age=40) compare
/EMMEANS=TABLES(white) WITH(age=60) compare
/EMMEANS=TABLES(white) WITH(age=80) compare
/PRINT=PARAMETER
/CRITERIA=ALPHA(.05)
/DESIGN=age sex white age*sex age*white.
* Plot the fitted values as a function of age & sex.
GRAPH
/SCATTERPLOT(BIVAR)=age WITH Yprime BY sex BY white
/MISSING=LISTWISE.
* Plot the fitted values as a function of age & white.
GRAPH
/SCATTERPLOT(BIVAR)=age WITH Yprime BY white
/MISSING=LISTWISE.
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS