In a model consisting of 3 predictor variables in which one of the variables is an interaction term of the other two predictors, should my focus in the results be in the coefficient for the interaction term since that is what I am interested in, regardless of the statistical significance or direction of relationship of the other two predictors? In other words, should I ignore the other two variables, if my sole concern is the interpretation of the interaction term?
Hello Joan. Unfortunately, the response I just typed in here was lost due to some kind of error when I clicked Add. I don't have time to repeat it all, but here is the syntax for an example you can study.
* Save data file data1_1.sav from:
* http://www.jeremymiles.co.uk/regressionbook/data/ .
NEW FILE.
DATASET CLOSE all.
* Change path to where you store data file data1_1.sav.
GET FILE='C:\bw\SPSS\data\Miles\data1_1.sav'.
* Estimate OLS regression model with:
* Y = Grade
* X1 = books
* X2 = attent
* X3 = books*attend.
* First, use REGRESSION proecdure.
COMPUTE BOOKSxATTEND = books*attend.
REGRESSION
/STATISTICS COEFF OUTS CI(95) R ANOVA
/DEPENDENT grade
/METHOD=ENTER books attend BOOKSxATTEND.
* Coefficient for Attend = slope for relationship between
* Attend and Grade when Books = 0.
* Center Books on 2 to get the slope when Books = 2.
* Note that the product term must be recomputed too.
* The TEMPORARY command below is in effect until the first
* data pass, which is caused by the REGRESSION command.
TEMPORARY.
COMPUTE books = books - 2.
COMPUTE BOOKSxATTEND = books*attend.
REGRESSION
/STATISTICS COEFF OUTS CI(95) R ANOVA
/DEPENDENT grade
/METHOD=ENTER books attend BOOKSxATTEND.
* Center Books on 4 to get the slope when Books = 4.
* Note that the product term must be recomputed too.
TEMPORARY.
COMPUTE books = books - 4.
COMPUTE BOOKSxATTEND = books*attend.
REGRESSION
/STATISTICS COEFF OUTS CI(95) R ANOVA
/DEPENDENT grade
/METHOD=ENTER books attend BOOKSxATTEND.
* -- End of syntax.
Pay attention to the 3 tables of coefficients, and notice how the constant and the coefficient for Attend change, but the other two coefficients remain the same. The Constant, as usual shows the fitted value of Y when all explanatory variables are set to 0. (When a centered variable is set to 0, the original variable is set to the centering value.) Notice too that for every one unit increase in Books, the slope for Attend increases by .735, the coefficient for the product term.
I hope this clarifies things further.
EDITS
Just thought I'd add that instead of pasting 3 lots of REGRESSION syntax, this would have been a nice place to use a macro. I could have done something like this:
* Use a macro with centering values for Books and Attend as arguments.
DEFINE !MyReg
( CVbooks = !TOKENS(1) /
CVattend = !TOKENS(1) )
TEMPORARY.
COMPUTE books = books - !CVbooks.
COMPUTE attend = attend - !CVattend.
COMPUTE BOOKSxATTEND = books*attend.
REGRESSION
/STATISTICS COEFF OUTS CI(95) R ANOVA
/DEPENDENT grade
/METHOD=ENTER books attend BOOKSxATTEND.
!ENDDEFINE.
!MyReg CVbooks = 0 CVattend = 6.
!MyReg CVbooks = 2 CVattend = 6.
!MyReg CVbooks = 4 CVattend = 6.
It is important to report all predictors in a model. This allows the reader to make their own conclusions. All the more reason to report all variables if the direction is different from what you expected.
Hello Joan, thank you for the response!
I understand that I need to report all the different coefficients, but my question was about interpretation. If what I am interested in showing is through the interaction term, than does it matter if the other variables are not in the expected direction. In other words, if the interaction term is what I expected and it is statistically significant, does it matter to my bottom line, if the other predictors are not statistically significant or if they are not in the expected direction?
Take a look at Andrew Hayes' website, as he has SPSS (and SAS) Macros and tools that you can use to probe an interaction effect in regression using simple slopes:
http://www.afhayes.com/spss-sas-and-mplus-macros-and-code.html
You need to take all three predictor variables in to account if there are main effects (for x1 and x2) and an interaction ( for x1 * x2).
For an example of how this can be done look at below manual (out of sample predictions) which is on Research Gate - this is for MLwiN but other software has predictive capabilities .
Manual supplement for MLwiN Version 2.14
Jon Rasbash, Chris Charlton, Kelvyn Jones, Rebecca Pillinger
https://www.researchgate.net/publication/234015221_Manual_supplement_for_MLwiN_Version_2.14
To my mind you really have to graph up the changing relation with the predicted outcome and associated confidence intervals for a characteristic set of values of the predictors. It is very difficult to see what is going on from the estimates and standard errors as the whole point of the interaction is the effects change with different values of the predictor variable.
Imagine Y is attainment on a test, x1 is prior ability and x2 is a categorical variable where 1 = boy and girl = 0. The beta for boy (x2) gives you the difference in attainment for boys and girls but only for when prior ability is equal to zero, and this gender gap will be changing if beta(boy* ability) is important – you need predictions and a graph to really appreciate this - estimates and SE's are not enough.
Data Manual supplement for MLwiN Version 2.14
I strongly recommend Brambor, Clark, & Golder's article "Understanding Interaction Models: Improving Empirical Analyses." in Political Analysis. You can find the article and some additional materials in the following website:
https://files.nyu.edu/mrg217/public/interaction.html
Hope it helps!
The 1991 book by Aiken & West remains very helpful, I think.
Aiken, L. S., & West, S. G. (1991). Multiple regression: Testing and interpreting interactions. Sage.
However, some of their SPSS methods were not as efficient as they could have been, and since 1991, there are some new features in SPSS that one can take advantage of (e.g., OMS). Here is a small example that might give you some ideas about how to explore the nature of your interaction.
* This syntax requires a version of SPSS that supports OMS & GGRAPH.
* Save data file data1_1.sav from:
* http://www.jeremymiles.co.uk/regressionbook/data/ .
NEW FILE.
DATASET CLOSE all.
* Change path to where you store data file data1_1.sav.
GET FILE='C:\bw\SPSS\data\Miles\data1_1.sav'.
* Estimate OLS regression model with:
* Y = Grade
* X1 = books
* X2 = attent
* X3 = books*attend.
* First, use REGRESSION proecdure.
COMPUTE BOOKSxATTEND = books*attend.
REGRESSION
/STATISTICS COEFF OUTS CI(95) R ANOVA
/DEPENDENT grade
/METHOD=ENTER books attend BOOKSxATTEND.
* The interaction is statistically significant.
* To explore the nature of the interaction, compute
* the fitted value of Y at selected combinations of X1 and X2
* and plot the fitted values. But first, make a scatter-plot
* to see what combinations of X1 and X2 are actually occurring
* in this dataset.
GRAPH
/SCATTERPLOT(BIVAR)=books WITH attend
/MISSING=LISTWISE.
* This plot suggests that it would be okay to compute
* fitted values of Y at all combinations of 0, 2, 4 and
* attend = 10, 15, 20. This can be done more easily with
* UNIANOVA than it can with REGRESSION. With UNIANOVA,
* one can get the fitted values with a series of EMMEANS
* sub-commands. If OMS is used, those fitted values can
* be saved to another dataset for plotting.
* As I'll be declaring a new dataset below, I better
* create a dataset name for the raw data.
DATASET NAME raw.
* OMS.
DATASET DECLARE EMMEANS.
OMS
/SELECT TABLES
/IF COMMANDS=['UNIANOVA'] SUBTYPES=['Estimated Marginal Means']
/DESTINATION FORMAT=SAV NUMBERED=TableNumber_
OUTFILE='EMMEANS'.
UNIANOVA grade WITH books attend
/METHOD=SSTYPE(3)
/INTERCEPT=INCLUDE
/EMMEANS=TABLES(OVERALL) WITH(books=0 attend=10)
/EMMEANS=TABLES(OVERALL) WITH(books=0 attend=15)
/EMMEANS=TABLES(OVERALL) WITH(books=0 attend=20)
/EMMEANS=TABLES(OVERALL) WITH(books=2 attend=10)
/EMMEANS=TABLES(OVERALL) WITH(books=2 attend=15)
/EMMEANS=TABLES(OVERALL) WITH(books=2 attend=20)
/EMMEANS=TABLES(OVERALL) WITH(books=4 attend=10)
/EMMEANS=TABLES(OVERALL) WITH(books=4 attend=15)
/EMMEANS=TABLES(OVERALL) WITH(books=4 attend=20)
/PRINT=PARAMETER
/PLOT=RESIDUALS
/CRITERIA=ALPHA(.05)
/DESIGN=books attend books*attend.
OMSEND.
* Activate the EMMEANS dataset and take a look at it.
DATASET ACTIVATE EMMEANS.
* The rows are numbered 1 to 9, corresponding to our 9 combinations of X1 and X2.
* To make a plot, I must recode 1-9 into books and attend values.
RECODE TableNumber_
(1 2 3 = 0)
(4 5 6 = 2)
(7 8 9 = 4) into books.
RECODE TableNumber_
(1 4 7 = 10)
(2 5 8 = 15)
(3 6 9 = 20) into attend.
FORMATS books attend (f2.0).
EXECUTE.
DATASET ACTIVATE EMMEANS.
GRAPH
/SCATTERPLOT(BIVAR)=attend WITH Mean BY books
/MISSING=LISTWISE.
* Make a plot with X = Attend, Y = Grade, and separate lines for Books = 0, 2, 4.
GGRAPH
/GRAPHDATASET NAME="graphdataset" VARIABLES=attend Mean books MISSING=LISTWISE REPORTMISSING=NO
/GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: attend=col(source(s), name("attend"))
DATA: Mean=col(source(s), name("Mean"))
DATA: books=col(source(s), name("books"), unit.category())
GUIDE: axis(dim(1), label("attend"))
GUIDE: axis(dim(2), label("Mean"))
GUIDE: legend(aesthetic(aesthetic.color.exterior), label("books"))
ELEMENT: point(position(attend*Mean), color.exterior(books))
GUIDE: legend(aesthetic(aesthetic.shape.interior), label("Number of Books"))
SCALE: cat(aesthetic(aesthetic.color.interior))
ELEMENT: line(position(smooth.linear(attend*Mean)), color.interior(books))
END GPL.
* Make a plot with X = Books, Y = Grade, and separate lines for Attend = 10, 15, 20.
GGRAPH
/GRAPHDATASET NAME="graphdataset" VARIABLES=attend Mean books MISSING=LISTWISE REPORTMISSING=NO
/GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: books=col(source(s), name("books"))
DATA: Mean=col(source(s), name("Mean"))
DATA: attend=col(source(s), name("attend"), unit.category())
GUIDE: axis(dim(1), label("books"))
GUIDE: axis(dim(2), label("Mean"))
GUIDE: legend(aesthetic(aesthetic.color.exterior), label("attend"))
ELEMENT: point(position(books*Mean), color.exterior(attend))
GUIDE: legend(aesthetic(aesthetic.shape.interior), label("Attendance"))
SCALE: cat(aesthetic(aesthetic.color.interior))
ELEMENT: line(position(smooth.linear(books*Mean)), color.interior(attend))
END GPL.
Thank you Bruce and I actually just finished reading the Aiken and West book--very helpful indeed.
If the interaction of two predictors is significant, then the the main effects are for these two predictors are reported by normally ignored in the interpretation. The third predictor should be interpreted. Does that help?
I think it's worth reminding everyone that the question was about an OLS regression model, not a two-way ANOVA. The model has X1, X2, and X1*X2 as explanatory variables. In that model, the coefficient for X1 gives the slope for the relationship between X1 and Y when X2 = 0; and the coefficient for X2 gives the slope for the relationship between X2 and Y when X1 = 0. So these are *partial effects*, not main effects of the type one would see in ANOVA. In ANOVA terminology, they are "simple main effects", not main effects that involve averaging across the levels of the other variable.
Thank you Bruce for the clarification. So how would the sign/magnitude of these partial effects be interpreted? Would you offer a concrete example to illustrate?
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS