Here is a quick guide to doing this in Fiji/ImageJ. This assumes a 2D image of a single fluorescent label. You will need the hysteresis thresholding plugin written by Thomas Boudier. Download at http://imagejdocu.tudor.lu/doku.php?id=plugin:segmentation:hysteresis_thresholding:start

In Fiji or ImageJ, open the macro editor under the menu Plugins>New>Macro then paste the following and run it for an example. Change step 2 to open your image, or omit it to run on an already open image. Adjust the lower and upper threshold values for the hysteresis plugin to get optimal results.

// 1. set up the measurements

run("Set Measurements...", "area feret's integrated redirect=None decimal=9");

run("Colors...", "foreground=white background=black selection=red");

// 2. open your image

// The invert step is a custom step to mimic fluorescent image.

// It only applies to the CellColony image

run("Cell Colony (31K)");

imp=getImageID();

title=getTitle();

run("Invert");

// 3. subtract background if illumination is uneven

run("Subtract Background...", "rolling=128 sliding");

// 4. run hysteresis thresholding

// this method determines the lower threshold with the Huang method

// and the upper threshold with the Yen method. Change methods as necessary

// to get a better fit. Optionally, hard value limits can be used

setAutoThreshold("Huang dark");

getThreshold(lowerHuang,upperHuang);

setAutoThreshold("Yen dark");

getThreshold(lowerYen,upperYen);

resetThreshold

run("hysteresis ", "high="+lowerYen+" low="+lowerHuang);

// 5. watershed the hysteresis image

selectWindow("Hysteresis");

run("Watershed");

// 6. analyze particles to get results

run("Analyze Particles...", "size=0-Infinity circularity=0.00-1.00 show=Nothing display add in_situ");

// cleanup actions

selectWindow("Trinarisation");

rename(title+"_Trinarisation");

selectWindow("Hysteresis");

rename(title+"_Hysteresis");

selectImage(imp);

roiManager("Show All without labels");

Bela, Fiji offers good tools for something like this, but you'll probably have to write something yourself to really make it optimal for your analysis. What is your somatic stain? And is this in vivo or in vitro? Flourescence intesnity is a really difficult thing to address in an automated fashion if you're working in vivo due to varying degrees of background to noise ratio in the tissue. We used a Fiji script to analyse flour. intensity of single intraepidermal nerve fibers in skin samples, measuring fiber density (so the relation was to µm²). Details of that specific script can be found in Hirth et al, Pain. 2013 Nov;154(11):2500-11.

Another option would be the neuron tracing software from MBF (Neurolucida), but it is expensive, so would only work if somebody in your environment already has such a work station.

Good luck!

Thanks Maren!

I'll check the Fiji first. ..but you're right, Neurolucida should be able to do such thing. There is a nearby lab that has it. I worth to ask. Thanks a lot!!!!

best,

Bela

Use Image J Convert images to 8bit, do threshold and analyze particles (set the value). This is built in feature in 1.4 and later version of image J. This will give you count and size.

Intensity will be good if you have monochrome images? Use image J and find Extrax plugin.

Monochrome is OK. This sounds easy, how come I have not seen it. I definitely have to check it out!

Thanks Mohammad!

best,

Bela

Now this is a tough question. To count the number of the cells is easy, the ImageJ is perfect for this. To measure the size and the intensity is another question. Applying any threshold to your pictures brings you unacceptable subjective error, which due to the nonlinear interrelationship in your system might give you false outcome at the end. It might give you semi-quantitative data however, which could serve you well after using strong statistical analysis.

An intensity distribution curve analysis would be recommended, but I would scratch my head how to automate the process.

Here is a quick guide to doing this in Fiji/ImageJ. This assumes a 2D image of a single fluorescent label. You will need the hysteresis thresholding plugin written by Thomas Boudier. Download at http://imagejdocu.tudor.lu/doku.php?id=plugin:segmentation:hysteresis_thresholding:start

In Fiji or ImageJ, open the macro editor under the menu Plugins>New>Macro then paste the following and run it for an example. Change step 2 to open your image, or omit it to run on an already open image. Adjust the lower and upper threshold values for the hysteresis plugin to get optimal results.

// 1. set up the measurements

run("Set Measurements...", "area feret's integrated redirect=None decimal=9");

run("Colors...", "foreground=white background=black selection=red");

// 2. open your image

// The invert step is a custom step to mimic fluorescent image.

// It only applies to the CellColony image

run("Cell Colony (31K)");

imp=getImageID();

title=getTitle();

run("Invert");

// 3. subtract background if illumination is uneven

run("Subtract Background...", "rolling=128 sliding");

// 4. run hysteresis thresholding

// this method determines the lower threshold with the Huang method

// and the upper threshold with the Yen method. Change methods as necessary

// to get a better fit. Optionally, hard value limits can be used

setAutoThreshold("Huang dark");

getThreshold(lowerHuang,upperHuang);

setAutoThreshold("Yen dark");

getThreshold(lowerYen,upperYen);

resetThreshold

run("hysteresis ", "high="+lowerYen+" low="+lowerHuang);

// 5. watershed the hysteresis image

selectWindow("Hysteresis");

run("Watershed");

// 6. analyze particles to get results

run("Analyze Particles...", "size=0-Infinity circularity=0.00-1.00 show=Nothing display add in_situ");

// cleanup actions

selectWindow("Trinarisation");

rename(title+"_Trinarisation");

selectWindow("Hysteresis");

rename(title+"_Hysteresis");

selectImage(imp);

roiManager("Show All without labels");

Thank you for sharing the Macro