!HERE MY CODE:
! 2D model: Laminated Composite PLANE182 (4 nodes) and crack INTER202 (4 nodes)
! Crack propagation using VCCT technique, CINT and CGROW commands
FINISH
/CLEAR
/TITLE,Test Crack Propagation
/PREP7
/UIS,MSGPOP,3
SELTOL,1e-6
! Dimensions in mm
ltot = 100 ! Length of the rectangle
th_ply = 10 ! Ply thickness (laminate)
nb_ply = 2 ! Number of plies
th_tot = th_ply*nb_ply ! Total thickness
th_branch = 5 ! Thickness of the branching (crack propagation)
a0 = 5 ! Existing crack length
lcrack1 = 10 ! Propagation length before branching @ 45deg.
ext_max = ltot - a0 ! Max. extension length for crack propagation
disp1 = 0.02 ! Displacement #1 (small)
disp2 = 1 ! Displacement #2
l_elem = 0.6 ! General element length
tolerance = 0.00001
! Non-linear parameters
subst1 = 4
substmax1 = 4
substmin1 = 4
subst2 = 200
substmax2 = 200
substmin2 = 10
! Element types
! Composite
ET,1,PLANE182
KEYOPT,1,1,2 !
KEYOPT,1,3,2 ! Plane strain
! Interface
ET,2,INTER202
KEYOPT,2,2,1 ! VCCT
KEYOPT,2,3,2 ! Plane strain
! Mechanical Properties for Material 1: Composite
MP,EX,1,1.353e5
MP,EY,1,9.0e3
MP,EZ,1,9.0e3
MP,GXY,1,5.2e3
MP,PRXY,1,0.24
MP,PRXZ,1,0.24
MP,PRYZ,1,0.46
g1c=0.28 ! critical energy-release rates
g2c=0.80
g3c=0.80
TB,CGCR,1,,3,LINEAR
TBDATA,1,g1c,g2c,g3c
!!!!!!!!!!!!
! Geometry !
!!!!!!!!!!!!
K,1,0,0
K,2,0,th_tot
K,3,ltot,th_tot
K,4,ltot,0
K,5,0,th_ply
K,6,0,th_ply
K,7,a0,th_ply
K,8,a0,th_ply
K,9 ,a0+lcrack1,th_ply
K,10,a0+lcrack1,th_ply
K,11,a0+lcrack1+th_branch,th_ply+th_branch
K,12,a0+lcrack1+th_branch,th_ply+th_branch
K,13,ltot,th_ply+th_branch
K,14,ltot,th_ply+th_branch
K,15,ltot,th_ply
K,16,ltot,th_ply
K,17,a0+lcrack1,th_ply
A,1,5,7,9,15,4
A,10,12,14,16
A,6,2,3,13,11,17,8
ALLS
! Meshing
LESIZE,ALL,l_elem
ALLS
MSHKEY,2 ! Mapped Meshing
TYPE,1 $ MAT,1
AMESH,ALL
ALLS
NSEL,S,LOC,X,0,a0-tolerance
NSEL,R,LOC,Y,th_ply
CM,nodes_a0,NODE
ALLS
CMSEL,U,nodes_a0
NUMMRG,NODES
NUMMRG,KP
ALLS
! Components for creating the interface elements
ASEL,S,AREA,,1,2
ESLA,S
CM,elem_bot,ELEM
ASEL,S,AREA,,3
ESLA,S
CM,elem_top,ELEM
ALLS
NSEL,U,LOC,X,0
NSEL,U,LOC,X,ltot
NSEL,U,LOC,Y,0
NSEL,U,LOC,Y,th_tot
ESLN,S
TYPE,2 $ MAT,5
CZMESH,elem_bot,elem_top
ALLS
ESEL,S,TYPE,,2
CM,crack_path,ELEM ! Elements for crack path
NSLE,S,1
CM,nodes_prop,NODE
NSEL,R,LOC,X,a0
CM,crack_tip,NODE ! Component for the nodes at the Crack Tip
ALLS
SAVE,test_crack,DB
/SOLU
NLGEOM,ON
AUTOTS,ON
NSUBST,subst1,substmax1,substmin1
! 1st calculation
TIME,1
NSEL,S,LOC,Y,0
D,ALL,ALL
CMSEL,S,elem_top
NSLE,S,1
NSEL,R,LOC,X,0
D,ALL,UY,disp1
D,ALL,UX,0
ALLS
! Definition of the crack
CINT,NEW,1 ! crack id
CINT,TYPE,VCCT ! vcct calculation
CINT,CENC,nodes_prop,crack_tip,0,1
ALLS
! Crack growth parameters
CGROW,NEW,1 ! crack growth set
CGROW,CID,1 ! CINT ID for VCCT calculation
CGROW,CPATH,crack_path ! crack path
CGROW,FCOP,MTAB,1 ! fracture criterion: TBDATA material 1
CGROW,STOP,CEMX,ext_max
CGROW,DTIME,2e-3
CGROW,DTMIN,2e-3
CGROW,DTMAX,2e-3
CGROW,FCRA,1
ALLS
OUTRES,ALL,ALL
ALLS
SOLVE
! 2nd calculation
TIME,2
CMSEL,S,elem_top
NSLE,S,1
NSEL,R,LOC,X,0
D,ALL,UY,disp2
D,ALL,UX,0
ALLS
NSUBST,subst2,substmax2,substmin2
ALLS
OUTRES,ALL,ALL
SOLVE
/POST1
SET,LAST
ALLS
PLNS,U,Y
My question rather is: can I remove the INTER202 Elements. Because at the moment, they still exist after delamination but don´t do anything.
Hallo Christof, ich versuche zur Zeit auch Risswachstum in Verbundwerkstoffe zu simulieren. Wollte fragen ob es bei Dir geklappt hat.Könntest du mir bitte dann den Code schicken? Meine Email: [email protected]
Viele Grüße
Hello friends,
Can CGROW command be used with shell elements?
- Badges
- Science topic