Jane C. Holland : what you need is a loop. In Stata you can create one using the foreach command.

foreach var of var of varlist b1-v14 {

display "Correlation of cvar with `var'"

pbis `var' cvar

}

The first line sets up an placeholder called var. You can call this entity anything you like, I just call it var so that it's easy to see in the subsequent lines that it acts as a placeholder for a variable name. I use num when I'm creating a placeholder for a list of numbers.

The line ends with a { which will enclose the commands to be processed.

The next line is a convenience line. It displays the text in the double quotes, but when Stata reads `var' it substitutes the name of the variable that currently occupies the placeholder. On the first iteration, that will be variable b1, then b2 etc as Stata works its way through the 14 b-variables.

The next line is your pbis command. Note how every time I refer the placeholder I put single quotes around it – the opening single quotes looks like a backtick and you may have to hunt for it on your keyboard. On my Mac it's to the left of z.

The last line closes the loop with the matching }.

Stata loops through the commands enclosed in the { }, substituting b1 for `var' then b2 etc.

You could put the whole lot into a do-file :

log using "Point biserials.txt",text replace

foreach var of var of varlist b1-v14 {

display "Correlation of cvar with `var'"

pbis `var' cvar

}

log close

The text option is clear enough – use a plain text log file. The replace option simply says to replace the file if it exists. You can also give the append option if you want to add something to an existing log file.

Hello Jane C. Holland (and Ronán Michael Conroy). If your Stata version is new enough, you could use the -esize- command, which is an official Stata command.

I had not heard of the (user-written) package -pbis- before reading your question, so decided to try it. And to my surprise, I found that it did not give the same result as -pwcorr- or (user-written) -corrci-. That surprised me because conventional wisdom says that the point biserial correlation is equivalent to Pearson r computed on the same data. The -esize- command, on the other hand, does give the same result as -pwcorr-. See some of my code below. After some more tinkering around, I was able to match the result from -pbis- when I calculated rpb "by hand" using the sn-1 formula on this Wikipedia page:

• https://en.wikipedia.org/wiki/Point-biserial_correlation_coefficient

My best guess right now is that the author of the pbis package also used that equation, and that it is wrong. Either that, or the author of pbis and I both made the same mistake in coding it. I need to tinker around a bit more to figure that out. In either case, I suggest that you use the official Stata command -esize- rather than -pbis-.

HTH.

clear

sysuse auto

fre foreign

* Variable foreign is coded 0/1

* Conventional wisdom says that r_pb = Pearson r.

pwcorr foreign mpg

* findit corrci // if you need to install corrci

corrci mpg foreign

* Now use the -pbis- package.

* findit pbis // if you need to install pbis

pbis foreign mpg

* Strange. r_pb should be equivalent to Pearson r, but it is NOT.

* The -esize- command can also compute r_bp. Let's see what it reports.

esize twosample mpg, by(foreign) pbcorr

* -esize- gives the same magnitude, but with the opposite sign.

* If I reverse-code, presumably, I'll get the same sign too.

generate byte domestic = !foreign

esize twosample mpg, by(domestic) pbcorr

corrci mpg foreign

matrix list r(corr) // show more decimals

* The correlation now matches what I get from -corrci-, but the CI does not.

* Summary so far!

* -pbis- is not giving the the same result as -pwcorr-, -esize- or -corrci-.

* Let's calculate it by hand using the equation shown here:

* https://en.wikipedia.org/wiki/Point-biserial_correlation_coefficient

* Used stored results from the -ttest- command

quietly ttest mpg, by(foreign)

local M1 = r(mu_1)

local n1 = r(N_1)

local M0 = r(mu_2)

local n0 = r(N_2)

local s = r(sd)

local n = r(N_1) + r(N_2)

local rpb = ((`M1'-`M0')/`s')*sqrt(`n1'*`n0'/(`n'*(`n-1')))

display "Hand computation of r_pb with s_n-1 version = " `rpb'

* Hmm. Strange indeed. My hand calculation using the equation

* from Wikipedia matches the result from -pbis-, and neither are

* "equivalent" to Pearson r, as I would expect.

* Used stored results from the -ttest- command

quietly ttest mpg, by(foreign)

local M1 = r(mu_1)

local n1 = r(N_1)

local M0 = r(mu_2)

local n0 = r(N_2)

local n = r(N_1) + r(N_2)

local sigma = sqrt(r(sd)^2*(`n'-1)/`n')

local rpb = ((`M1'-`M0')/`sigma')*sqrt(`n1'*`n0'/`n'^2)

display "Hand computation of r_pb with s_n version = " `rpb'

* This result matches what I get using -esize-, -pwcorr- and -corrci-.

* This suggests the s_n-1 equation on the Wikipedia page is wrong,

* or that I have made a mistake in coding it.

Since my last post, I discovered a coding error in my first attempt to implement the so-called sn-1 equation for rpb on the Wikipedia page:

• https://en.wikipedia.org/wiki/Point-biserial_correlation_coefficient

I was using stored results from the -ttest- command, and stored the key ones I wanted as local macros. Then I did this:

local rpb1 = ((`M1'-`M0')/`s')*sqrt(`n1'*`n0'/(`n'*(`n-1')))

And when I did it that way, I got the same result -rpbis- gives me, which is not the same value I get when I compute an ordinary Pearson r.

While staring at my code, I then noticed that `n-1' should be `n'-1, as in the next line:

local rpb2 = ((`M1'-`M0')/`s')*sqrt(`n1'*`n0'/(`n'*(`n'-1)))

With that correction, my "hand calculation" using the sn-1 equation does give the same result as an ordinary Pearson r.

I can only assume that the same error is present in the pbis.ado file, although I have not been able to track it down thus far.

Finally, in my tinkering around to figure out why -pbis- was giving a different result, I also discovered that -esize- with the pbcorr option reverses the sign you get for the Pearson r for reasons I cannot fathom. I think I'll have to post to Statalist to ask about that! (I also noticed that -esize- gives a different CI for rpb than I get with Nick Cox's -corrci- package.)

So Jane C. Holland, this all causes me to advise you to not use -pbis-! If you just need the point-biserial correlations, just use one of the commands that computes Pearson r, because a point-biserial correlation is equivalent to Pearson r when one variable is dichotomous and the other is quantitative.

PS- The code for my tinkering is attached, in case anyone is interested.

Bruce Weaver – that's fascinating. And impressive that you sleuthed it down to that level of detail. I wasn't aware that esize had point biserial correlations. Stata has become so vast that I wonder if anyone, even Bill Gould, knows everything it can do!

FYI, I started a Statalist discussion about this issue. Anyone who is interested can view it here.

• https://www.statalist.org/forums/forum/general-stata-discussion/general/1690078-methods-for-computing-the-point-biserial-correlation

Bruce Weaver Thank you so much for such attention to detail in looking at the code and answering! I'd calculated the CPB previously in SPSS (our institution has since moved to STATA) and looking at an old data set (& manually correcting total score per item) yes, pbis gives different results to that SPSS CPB, while pwcorr and esize compute well (with the reversed sign in esize). Thank you for suggesting them.

Ronán Michael Conroy I haven't used the foreach command before, and am not getting it to work. pwcorr Q1 Score is the individual command & works well as above - the other bvars are Q2 Q3 etc. (there are other columns & variables in the dataset, but I can certainly strip them out if needed). How exactly should I parse the foreach command? My javascript is usually limited to copy-paste... I've tried a few variations of the bvar list in the first line... should i be listing Q1 Q2 Q3 etc with a space each, or bQ1-vQ14. Some variations that I've tried:

foreach var of var of varlist Q1 Q2 Q3 Q4 {

display "Correlation of Score with `var'"

pwcorr `var' Score

}

foreach var of var of varlist Q1-v14 {

display "Correlation of Score with `var'"

pwcorr `var' Score

}

Hello Jane C. Holland. Here is a toy example that works. Replace my b1 to b5 with your own list of binary variables, and replace mpg with your continuous variable.

* Generate some data to illustrate

clear

sysuse auto

* Make 5 copies of binary variable foreign

forvalues i = 1/5 {

generate byte b`i' = !foreign // Notice the reverse coding!

}

* This is where the code you want starts.

foreach var of varlist b1 b2 b3 b4 b5 {

display "Correlation of mpg with `var'"

esize twosample mpg, by(`var') pbcorr

}

* If variables are contiguous in the file, use the shortcut b1-b5

foreach var of varlist b1-b5 {

display "Correlation of mpg with `var'"

esize twosample mpg, by(`var') pbcorr

}

Jane C. Holland – mea culpa! I should have read my own code. Bruce Weaver was correct : foreach var of varlist is what I should have written. Somehow I glitched and wrote foreach var of var of varlist…

Ahah! Facile factu :P Yes that works now Ronán Michael Conroy - thank you again Bruce Weaver :)