I wish to use SPSS to achieve minimum-maximum normalization (from 0 to 1)) for 5 variables. How can I do that?
Hello Henry. You've not said whether you want to use the observed Min and Max values in your data, or the theoretically possible Min and Max values, if there are such things. E.g., if your variables are 5-point Likert-type items, the theoretically possible Min and Max values are 1 and 5. But the observed Min might be > 1 and the observed Max < 5. If you want to use the observed Min and Max values, you can get them via the AGGREGATE command. See the toy example below. HTH.
* Read in some data to illustrate.
* I'll assume 5-point Likert-type items.
NEW FILE.
DATA LIST LIST / v1 TO v5 (5F1).
BEGIN DATA
5 2 4 5 5
1 5 4 4 4
5 1 4 2 4
2 4 3 1 3
3 4 3 1 1
2 1 4 1 3
1 4 2 1 5
1 5 2 5 5
1 2 5 3 4
1 4 4 3 4
END DATA.
* Min-Max normalized score = (value-min)/(max-min).
* Source: https://www.codecademy.com/article/normalization.
* It is not clear if Henry wants to use the observed
* Min and Max values, or the theoretically possible
* Min and Max values. I'll do both.
* Henry, the code you need starts here.
* Use AGGREGATE to get the observed min and max values.
AGGREGATE
/OUTFILE=* MODE=ADDVARIABLES
/BREAK=
/ObsMin1 to ObsMin5 = MIN(v1 to v5)
/ObsMax1 to ObsMax5 = MAX(v1 to v5).
LIST.
DO REPEAT
v = v1 to v5 /
ObsNorm = ObsNorm1 to ObsNorm5 /
ExpNorm = ExpNorm1 to ExpNorm5 /
ObsMin = ObsMin1 to ObsMin5 /
ObsMax = ObsMax1 to ObsMax5.
* Normalize using the observed Min & Max values.
COMPUTE ObsNorm = (v-ObsMin)/(ObsMax-ObsMin).
* Normalize using the possible Min & Max values.
COMPUTE ExpNorm = (v-1)/(5-1).
END REPEAT.
LIST.
Go to "Transform" in the top menu. Select "Compute Variable." Then. In the "Target Variable" box, enter a new name for your normalized variable, such as "Var1_Normalized." N]Thereafter, Replace "Var1" with the actual variable name. Repeat this process for each variable, changing the variable name accordingly. In the "Numeric Expression" box, enter the formula for normalization: scssCopy code(Var1 - MIN(Var1, Var2, Var3, Var4, Var5)) / (MAX(Var1, Var2, Var3, Var4, Var5) - MIN(Var1, Var2, Var3, Var4, Var5)) and click Ok. Repeat steps 3-5 for the remaining variables (Var2 to Var5), creating new normalized variables for each. You're welcome sir.
Thanks to you both, Tolu and Bruce. I will attempt both approaches.
Tolulope Gbayisomore, the MIN and MAX functions you are using return the MIN and MAX values across variables within each row. I may be wrong, but I think Henry Okuchukwu Ebili wants to use the MIN and MAX across rows within each variable. I added your computation to the ones I posted earlier to compare the results. See below.
* Tolulope Gbayisomore's suggestion.
DO REPEAT
v = v1 to v5 /
TG = TG1 to TG5.
COMPUTE TG = (v - MIN(v1 to v5)) / (MAX(v1 to v5) - MIN(v1 to v5)).
END REPEAT.
* Show the results for the 3 methods.
LIST ObsNorm1 ExpNorm1 TG1.
LIST ObsNorm2 ExpNorm2 TG2.
LIST ObsNorm3 ExpNorm3 TG3.
LIST ObsNorm4 ExpNorm4 TG4.
LIST ObsNorm5 ExpNorm5 TG5.
Here is the output from the 5 LIST commands.
ObsNorm1 ExpNorm1 TG1
1.00 1.00 1.00
.00 .00 .00
1.00 1.00 1.00
.25 .25 .33
.50 .50 .67
.25 .25 .33
.00 .00 .00
.00 .00 .00
.00 .00 .00
.00 .00 .00
ObsNorm2 ExpNorm2 TG2
.25 .25 .00
1.00 1.00 1.00
.00 .00 .00
.75 .75 1.00
.75 .75 1.00
.00 .00 .00
.75 .75 .75
1.00 1.00 1.00
.25 .25 .25
.75 .75 1.00
ObsNorm3 ExpNorm3 TG3
.67 .75 .67
.67 .75 .75
.67 .75 .75
.33 .50 .67
.33 .50 .67
.67 .75 1.00
.00 .25 .25
.00 .25 .25
1.00 1.00 1.00
.67 .75 1.00
ObsNorm4 ExpNorm4 TG4
1.00 1.00 1.00
.75 .75 .75
.25 .25 .25
.00 .00 .00
.00 .00 .00
.00 .00 .00
.00 .00 .00
1.00 1.00 1.00
.50 .50 .50
.50 .50 .67
ObsNorm5 ExpNorm5 TG5
1.00 1.00 1.00
.75 .75 .75
.75 .75 .75
.50 .50 .67
.00 .00 .00
.50 .50 .67
1.00 1.00 1.00
1.00 1.00 1.00
.75 .75 .75
.75 .75 1.00
Yes, you are right, Bruce Weaver. I want to perform the min-max normalization within each of the variables, separately. Not across the variables. I could easily do it in Excel spreadsheet, and transfer the data back to SPSS; but I want to reduce the process of moving from one software to another, if I can help it.
- Badges
- Science topic
- Similar topics
- Psychology