You can use the following code: You need to have gnrfet model in the same folder

.TITLE TWA FOR 6T

.option brief

.options POST

.options INGOLD=2 DCON=1

.global Vdd

.TEMP 25

.lib 'gnrfet.lib' GNRFET

*****************************************

.PARAM VDD1 = gauss(0.5, 0.1,3)

.PARAM VDD = VDD1

.PARAM L = gauss(16n, 0.1,3)

****************************

.param gnd=0 supply = vdd

.PARAM tstep=10ps tstop=2000ns

.PARAM Vinitial=GND Vpulsed=supply td=5NS

+ tr=50ps tf=50ps PW=1000ns per='tr+tf+2*pw'

*___________________________________

*___________________________________

* Sources and digital inputs

*___________________________________

VVdd Vdd gnd supply

*___________________________________

*INITIAL DATA STORED IN THE CELL

.IC V(Q)= 0V

.IC V(QB)= 'SUPPLY'

*DATA

VBL BL 0 'SUPPLY'

VBLB BLB 0 0

*READ

VWL WL gnd pulse (Vinitial Vpulsed td tr tf PW per)

*_________________________

CBL BL gnd 50fF

CBLB BLB gnd 50fF

CWL WL gnd 50fF

*_________________________

*________________________________________

*Netlist, .SUBKCT, .ENDS, or .MACRO, .EOM

*________________________________________

* MAIN CIRCUIT

*________________________________________________

*-------------------CELL BEING READ-------------------------

XPL Q QB VDD VDD gnrfetpmos nRib=6 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

XNL Q QB 0 0 gnrfetnmos nRib=6 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

XPR QB Q VDD VDD gnrfetpmos nRib=6 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

XNR QB Q 0 0 gnrfetnmos nRib=6 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

XNAR BLB WL QB 0 gnrfetnmos nRib=9 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

XNAL BL WL Q 0 gnrfetnmos nRib=9 n=15 L='L' Tox=0.95n sp=2n dop=0.001 p=0

****_________________________________________________

.tran tstep tstop 

.measure tran WRITE_Time TRIG V(WL) VAL='0.1*SUPPLY' RISE=1 TARG V(Q) val='0.9*SUPPLY' RISE=1

.end

Hi Sayeed, Thanks for the detail netlist. I could run both read and write operation with independent netlist for determining the read SNM and write SNM separately. Probably for determining SRAM delay and power dissipation from transient analysis your netlist would help a lot. 

Best'

Fahad

Hi,

Can someone please share the SPICE netlist to determine the write SNM for SRAM cell?

Help will be highly appreciated.