Is there anyway to plot the results of logistic regression as a forest plot in SPSS?
If you mean you want to plot the odds ratios & 95% CIs for the variables in your model, you could do something like the following. If you want to plot the coefficients with 95% CIs rather than odds ratios, you'll have to compute the limits of the CIs yourself in the file saved via OMS. You could simply compute the natural log of the CI limits for the ORs. HTH.
NEW FILE.
DATASET CLOSE ALL.
GET FILE "C:\SPSSdata\bankloan.sav".
DATASET NAME raw.
* OMS.
DATASET DECLARE logistic.
OMS
/SELECT TABLES
/IF COMMANDS=['Logistic Regression'] SUBTYPES=['Variables in the Equation']
/DESTINATION FORMAT=SAV NUMBERED=TableNumber_
OUTFILE='logistic' VIEWER=YES
/TAG = 'logistic'.
LOGISTIC REGRESSION VARIABLES default
/METHOD=ENTER age employ address income debtinc
/PRINT=CI(95)
/CRITERIA=PIN(0.05) POUT(0.10) ITERATE(20) CUT(0.5).
OMSEND TAG = ["logistic"].
DATASET ACTIVATE logistic.
COMPUTE Vfilter = Var2 NE "Constant".
FILTER by Vfilter.
VARIABLE LABELS Var2 "Variable".
* Chart Builder.
GGRAPH
/GRAPHDATASET NAME="graphdataset" VARIABLES=Var2 MAXIMUM(Upper)[name="MAXIMUM_Upper"]
MINIMUM(Lower)[name="MINIMUM_Lower"] MEAN(ExpB)[name="MEAN_ExpB"] MISSING=LISTWISE REPORTMISSING=NO
/GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: Var2=col(source(s), name("Var2"), unit.category())
DATA: MAXIMUM_Upper=col(source(s), name("MAXIMUM_Upper"))
DATA: MINIMUM_Lower=col(source(s), name("MINIMUM_Lower"))
DATA: MEAN_ExpB=col(source(s), name("MEAN_ExpB"))
COORD: rect(dim(1,2), transpose())
GUIDE: axis(dim(1), label("Variable"))
GUIDE: axis(dim(2), label("Odds Ratio & 95% CI"))
SCALE: linear(dim(2), include(0))
ELEMENT: interval(position(region.spread.range(Var2*(MINIMUM_Lower+MAXIMUM_Upper))),
shape(shape.ibeam))
ELEMENT: point(position(Var2*MEAN_ExpB), shape(shape.circle))
END GPL.
It's as easy as making coffee in your toaster.
Seriously, why not use RevMan, free software that actually does meta-analysis. http://community.cochrane.org/tools/review-production-tools/revman-5/revman-5-download
RevMan is designed to do the job.
I use Revman software, but the problem is the images that are made have poor resolution and are not accepted by many journals.
Nader, your original question is: " Is there anyway to plot the results of logistic regression as a forest plot in SPSS?" It says nothing about meta-analysis. Do you mean that you are meta-analyzing the results from several studies that used logistic regression, or that you are trying to plot the coefficients (or odds ratios) from your own multivariable regression model? My previous reply assumed you meant the latter. The subsequent posts seem to suggest that you are actually doing meta-analysis. Thank you for clarifying.
Bruce, Thank you for your response. Yes, indeed I meant to plot the coefficients or odds ratios from my own multivariable regression models.
- Badges
- Science topic
- Similar topics
- Mathematical Sciences
- Statistics
- Statistical Software
- SPSS