Hello Percy. One approach would be to partition your overall table into smaller tables. If your partitions are orthogonal, and if you use the likelihood ratio Chi-square, the Chi-square values for the sub-tables will add up to the Chi-square for the overall table. There is an example on a support page for IBM-SPSS (link given below). Here is a rough and ready translation into Stata code. HTH.

// Example from this IBM SPSS suport page:

// https://www.ibm.com/support/pages/partitioning-lr-chi-square-crosstabs-test-independence

clear

input school origin wt

1 1 90

1 2 12

1 3 78

2 1 13

2 2 1

2 3 6

3 1 19

3 2 13

3 3 50

end

tabulate school origin [fw=wt], lrchi2

local overall = r(chi2_lr)

// Subtable 1 : Row 1 vs Row 2; Column 1 vs Column 2.

recode school (1=1)(2=2)(3=.), gen(row)

recode origin (1=1)(2=2)(3=.), gen(col)

tabulate row col [fw=wt], lrchi2

local sub1 = r(chi2_lr)

// Subtable 2 : Row 1 vs Row 2; Columns 1&2 vs Column 3.

drop row col

recode school (1=1)(2=2)(3=.), gen(row)

recode origin (1 2 = 1)(3=2), gen(col)

tabulate row col [fw=wt], lrchi2

local sub2 = r(chi2_lr)

// Subtable 3 : Rows 1&2 vs Row 3; Column 1 vs Column 2.

drop row col

recode school (1 2 = 1)(2=3), gen(row)

recode origin (1=1)(2=2)(3=.), gen(col)

tabulate row col [fw=wt], lrchi2

local sub3 = r(chi2_lr)

// Subtable 4 : Rows 1&2 vs Row 3; Columns 1&2 vs Column 3

drop row col

recode school (1 2 = 1)(2=3), gen(row)

recode origin (1 2 = 1)(2=3), gen(col)

tabulate row col [fw=wt], lrchi2

local sub4 = r(chi2_lr)

display _newline ///

" LR Chisq for subtable 1 = "`sub1' _newline ///

" LR Chisq for subtable 2 = "`sub2' _newline ///

" LR Chisq for subtable 3 = "`sub3' _newline ///

" LR Chisq for subtable 4 = "`sub4' _newline ///

" Sum of LR Chisq values = " `sub1'+`sub2'+`sub3'+`sub4' _newline ///

"LR Chisq for overall table = " `overall'

And here is the output from that -display- command.

> "LR Chisq for overall table = " `overall'

LR Chisq for subtable 1 = .29419388

LR Chisq for subtable 2 = 1.3587925

LR Chisq for subtable 3 = 12.952875

LR Chisq for subtable 4 = 8.4303303

Sum of LR Chisq values = 23.036192

LR Chisq for overall table = 23.036192

The Chi-Square test using a crosstabulation of preparedness and racial identity does not take into account the ordinal measurement of preparedness. Using -ologit- instead followed by Long & Freese's & postestimation command -mchange- (ideally taking into account multiple comparisons with the option mcompare(sidak) would be more efficient.

For example:

ologit preparedness i.race

mchange, mcompare(sidak)

See also Richard Williams' lecture notes "Adjusted Predictions & Marginal Effects for Multiple Outcome Models & Commands": https://www3.nd.edu/~rwilliam/stats3/Margins05.pdf

as well as Scott Long and Jeremy Freese's notes "Why use m* commands instead of margins?": https://jslsoc.sitehost.iu.edu/web_spost13/sp13_whymstar.htm