I am not sure if this link answers your question, I had similar question one year age and got the link

https://www.stata.com/statalist/archive/2005-04/msg00678.html

There is also a very good discussion in the Stata documentation – see the PDF documentation that installed with your Stata. The appropriate bit is the discussion of example 3 in the help for mlogit (on page 1656 of Stata manual r!)

The multinomial logit regression models (estimated by mlogit in Stata), coefficients that are exponentiated are mainly relative risks ratios and NOT ratios of the odds. It's only true under the mere binary logit models estimated by logit command in Stata.

I think that the confusion over the RRR column heading in -mlogit- output comes down to the fact that in some disciplines, the terms relative risk and risk ratio are not seen as synonymous (as they are in epidemiology & related disciplines). In some disciplines, the relative risk of an event = risk of the event in a given group divided by the risk of a non-event in that same group. But that is exactly the same thing as the odds of an event in that group. I.e., in some disciplines and some statistical dialects, it seems that relative risk = odds. See #5 in this Statalist thread, for example:

• https://www.statalist.org/forums/forum/general-stata-discussion/general/545887-multinomial-logit-interpretation-rrr-vs-cor

Getting back to -mlogit- and the RRR heading, please note that the RRR values can be duplicated exactly by estimating a series of binary logistic regression models and displaying the odds ratios. Here's an example using the help file example Ronán pointed to. (I made a few minor modifications, such as the keep command.) HTH.

* Examples 1-3 for -mlogit- (in the PDF help file)

clear *

use http://www.stata-press.com/data/r15/sysdsn1

keep if !missing(insure) & !missing(nonwhite)

* Example 1

tabulate insure nonwhite, chi2 lrchi2 col

mlogit insure nonwhite

* Example 2: Treat insure==2 (Prepaid) as the reference category.

mlogit insure nonwhite, baseoutcome(2)

* Example 3: Displaying the "relative risk ratios"

mlogit, rrr

* Now show that the RRR values from -mlogit-

* can be duplicated using a pair of -logit- models.

* One of them will exclude row 3 from the cross-tabulation

* shown above, and one will exclude row 1. Both will use

* row 2 (Prepaid) as the reference category for the outcome variable.

* Generate two new DV variables for the two binary logit models

generate byte indemnity = insure==1 if insure < 3

generate byte uninsured = insure==3 if insure > 1

logit indemnity nonwhite, or nohead // Indemnity relative to Prepaid

logit uninsured nonwhite, or nohead // Uinsured relative to Prepaid

* Redo the -mlogit- model to see the table of RRR values again

mlogit insure nonwhite, baseoutcome(2) rrr noheader

* Notice that the RRR values match the ORs from the two -logit- models

The listcoef also gives us beta and exponentiated beta. I found people reporting odds ratio while using multinomial logistic regression in their analyses.

This is interesting discussion and from a quick look up, I can agree that RRR is actually odds ratio

Thank you, Brian, for bringing up this valuable discussion thread.

For some strange reasons the odds are called "relative risks" here (hence the name of the option), but the formula in the handbook shows that it's all about the odds, as you might expect

Relative Risk denotes the strength of exposure variables by comparison with each other or with reference one while Odds Ratio also denotes strength of exposure variable from outcome point of view; the ratio of odds obtained in the screening test. OR is more acceptable and meaningful in the study of diseases.

Please see the article describing the difference in how RRR and OR are calculated:

https://www.ncbi.nlm.nih.gov/pmc/articles/PMC4640017/

As “a” decreases with respect to “b” (probability of outcome becomes less), the odds and risk are similar. For rare events (i.e., if “a” is small and “a + b” approaches “b”), a/(a + b) ≈ a/b and risk approximates odds. Therefore, though “odds” does not represent true risk, its value is close to risk when the event rates are low (typically

There is some explanation here: https://www.stata.com/products/stb/journals/stb53.pdf

But it is not clear exactly that they are really calculating RRR, when the Book of Hosmer and Lemeshow clearly explain that multinomial logistic regression produces OR. Further, the name "Relative Risk Ratio" is totally inappropriate when data is cross-sectional and conveys prevalence.

My attempt to explain why the output from Stata's -mlogit- reports the RRR is in the attached PDF. HTH.