Dear Gurmohan Singh, 

The following link contains a discussion on the topic of concern and it gives the way to compute static noise margins (SNMs) of TCAM in H-Spice.

http://www.edaboard.com/thread253224.html

hoping this will be helpful,

Rafik

snm.graphical.sp

*Determination of 6T SRAM cell RSNM by graphical method as given by Seevinck_1987

*it is read SNM analysis of 6T sram cell during read mode at 25 temperature.

* you have to add PTM model file

********************************************************************

.TEMP 25.0000

.protect

* Donnot print the contents of library

.include 'D:\Dissertation\coding\model file\32nm_NMOS_bulk6769.pm'

.include 'D:\Dissertation\coding\model file\32nm_PMOS_bulk22584.pm'

* Load the library

.unprotect

*Sets global values

.GLOBAL VDD!

*Parameterize input element

.PARAM VDD = 1V

.PARAM L = 32n

.PARAM WN = '1*L'

.PARAM WP = '1*L'

.PARAM LNA = '1*L'

.PARAM WNA = '1*L'

.PARAM U = 0

.PARAM UL = '-VDD/sqrt(2)'

.PARAM UH = ' VDD/sqrt(2)'

.PARAM BITCAP = 1E-12

*Requesting Graph Data Format in binary

.OPTION POST

CBL BLB 0 BITCAP

CBLB BL 0 BITCAP

*MOSFET (we can specify additional parameters, such as W= L=, in the parameter list)

* m

* one inverter

MPL QD QB VDD! VDD! PMOS L='L' W='WP' 

+AD='WP*2.5*L' AS='WP*2.5*L' PD='2*WP+5*L' PS='2*WP+5*L'

+M=1

MNL QD QB 0 0 NMOS L='L' W='WN' 

+AD='WN*2.5*L' AS='WN*2.5*L' PD='2*WN+5*L' PS='2*WN+5*L'

+M=1

* one inverter

MPR QBD Q VDD! VDD! PMOS L='L' W='WP' 

+AD='WP*2.5*L' AS='WP*2.5*L' PD='2*WP+5*L' PS='2*WP+5*L'

+M=1

MNR QBD Q 0 0 NMOS L='L' W='WN' 

+AD='WN*2.5*L' AS='WN*2.5*L' PD='2*WN+5*L' PS='2*WN+5*L'

+M=1

* access transistors

MNAL BLB WL QBD 0 NMOS L='LNA' W='WNA' 

+AD='WNA*2.5*L' AS='WNA*2.5*L' PD='2*WNA+5*L' PS='2*WNA+5*L'

+M=1

MNAR BL WL QD 0 NMOS L='LNA' W='WNA' 

+AD='WNA*2.5*L' AS='WNA*2.5*L' PD='2*WNA+5*L' PS='2*WNA+5*L'

+M=1

*Independent voltage source

*v

VVDD! VDD! 0 DC=VDD

* when reading, use VDD in hold mode use 0

VWL WL 0 DC=vdd

*Initial condition

.IC V(BL) = VDD

.IC V(BLB) = VDD

* use voltage controlled voltage sources (VCVS)

* changing the co-ordinates in 45 degree angle

EQ Q 0 VOL=' 1/sqrt(2)*U + 1/sqrt(2)*V(V1)'

EQB QB 0 VOL='-1/sqrt(2)*U + 1/sqrt(2)*V(V2)'

* inverter characteristics

EV1 V1 0 VOL=' U + sqrt(2)*V(QBD)'

EV2 V2 0 VOL='-U + sqrt(2)*V(QD)'

* take the absolute value for determination of SNM

EVD VD 0 VOL='(V(V1) - V(V2))'

.DC U UL UH 0.01 

.PRINT DC V(QD) V(QBD) V(V1) V(V2)

*now we are getin1 exactaly same value as we geting from old method(graphical method)

.MEASURE DC MAXVD MAX V(VD) FROM=-500m to =500m

.MEASURE DC MINVD MIN V(VD) FROM=-500m to =500m

* measure SNM

*.MEASURE DC SNM param='1/sqrt(2)*MAXVD'

*CHANGE 0N 1 MAY 2015 MINVD VALUE ALWAYES BE -VE SO WE TAKE abs VALUE OF IT. NOW FIND MIN VALUE OF MAXVD AND MINVD.

.MEASURE DC SNM param='(1/sqrt(2)*MIN(MAXVD,ABS(minVD)))'

.END

hey we dont know